****************************** IGBT Electrical Parameters ***************************
** Product: FGH15T120SMD
** 1200V, 15A Field Stop IGBT
** Model Format: SPICE2G6
** LTSpiceIV
**-----------------------------------------------------------------------------------
.SUBCKT FGH15T120SMD C G E
LE   74 E  1.48n 
RE   83 74 1.57m  TC=1.05e-3
RC   85 C  43.56m TC=1.47e-3
RG   G 82  0.5
CGC  82 C  1p 
CGD  92 93 1.433n
CGE  E 82  1.12n 
M1   81 82 83 83 MOS W=1u L=1u          
Q1   83 81 85 VPNP 
R1   92 0 1
R2   91 94 1
RLV  95 0 1
DBE  85 81 DE 
DSD  83 81 DO 
DHV  94 93 DR
DLV  94 95 DR 1
D1   91 92 DLIM 
D2   94 0 DLIM
FFB  82 81 VFB 4.85
VFB  93 0 DC 0  
ESD  96 93 POLY(1) 83 81 19 1
MLV  95 96 93 93 SW           
EGD  91 0 82 81 1
DFRD E C FRD
.MODEL SW NMOS
+ LEVEL=3         VTO=0           KP=5
.MODEL VPNP PNP 
+ IS=8.07e-10     NF=1.5          BF=0.29         CJE=3.24e-9
+ TF=1.05e-9      XTB=1.56        EG=0.76
.MODEL MOS NMOS 
+ LEVEL=3         VMAX=5.0e5      THETA=0.0       ETA=2e-3
+ VTO=6.3         KP=5.25
.MODEL DR D
+ IS=1.0e-14      CJO=2.0e-10     VJ=0.38         M=0.78
.MODEL DO D 
+ IS=1.0e-14      BV=1310         CJO=5.74e-9     VJ=0.12   
+ M=1.02
.MODEL DE D
+ IS=1.0e-14      BV=30.0         N=2 
.MODEL DLIM D 
+ IS=1.00e-7
.MODEL FRD D 
+ IS=6.45e-10     RS=0.0658       EG=1.18         N=1.5
+ TRS1=1.05e-5    TRS2=1.07e-7    TT=7.12e-8      BV=1310
+ CJO=2.25e-10    M=0.72          VJ=0.65         XTI=23
+ IBV=2.5e-4
.ENDS
*$
******************************* IGBT Thermal Parameters ****************************
.SUBCKT FGH15T120SMD_Thermal TH TL
CTHERM1 TH 6 1.10e-5
CTHERM2 6 5  8.16e-4
CTHERM3 5 4  5.02e-3
CTHERM4 4 3  6.60e-3
CTHERM5 3 2  8.10e-3
CTHERM6 2 TL 3.01e-2
RTHERM1 TH 6 4.00e-4
RTHERM2 6 5  3.00e-3
RTHERM3 5 4  1.60e-2
RTHERM4 4 3  5.20e-2
RTHERM5 3 2  7.80e-2
RTHERM6 2 TL 3.01e-1
.ENDS FGH15T120SMD_Thermal
**----------------------------------------------------------------------------------
** Creation: Nov.-30-2016   Rev.: 1.0
** ON Semiconductor