*$
****************************** IGBT Electrical Parameters ***************************
** Product: FGH25T120SMD
** 1200V, 25A Field Stop IGBT
** Model Format: SPICE2G6
**-----------------------------------------------------------------------------------
.SUBCKT FGH25T120SMD C G E
LE   74 E  0.84n 
RE   83 74 2.76m  TC=4.02e-4
RC   85 C  14.66m TC=4.02e-4
RG   G 82  1.5
CGC  82 C  1p 
CGD  92 93 2.32n
CGE  E 82  2.02n 
M1   81 82 83 83 MOS W=1u L=1u          
Q1   83 81 85 VPNP 
R1   92 0 1
R2   91 94 1
RLV  95 0 1
DBE  85 81 DE 
DSD  83 81 DO 
DHV  94 93 DR
DLV  94 95 DR 1
D1   91 92 DLIM 
D2   94 0 DLIM
FFB  82 81 VFB 5.5
VFB  93 0 DC 0  
ESD  96 93 POLY(1) 83 81 19 1
MLV  95 96 93 93 SW           
EGD  91 0 82 81 1
DFRD E C FRD
.MODEL SW NMOS
+ LEVEL=3         VTO=0           KP=5
.MODEL VPNP PNP 
+ IS=1.07e-10     NF=1.5          BF=0.29         CJE=5.24e-9
+ TF=1.02e-9      XTB=1.56        EG=0.76
.MODEL MOS NMOS 
+ LEVEL=3         VMAX=5.0e5      THETA=0.0       ETA=2e-3
+ VTO=6.75        KP=6.15
.MODEL DR D
+ IS=1.0e-14      CJO=2.0e-10     VJ=0.78         M=0.79
.MODEL DO D 
+ IS=1.0e-14      BV=1310         CJO=9.54e-9     VJ=0.10   
+ M=1.15
.MODEL DE D
+ IS=1.0e-14      BV=30.0         N=2 
.MODEL DLIM D 
+ IS=1.00e-7
.MODEL FRD D 
+ IS=1.45e-13     RS=0.0308       EG=1.18         N=1.5
+ TRS1=1.05e-4    TRS2=4.07e-6    TT=4.02e-8      BV=1310
+ CJO=4.25e-10    M=0.52          VJ=0.62         XTI=23
+ IBV=2.5e-4 
.ENDS
*$
******************************* IGBT Thermal Parameters ****************************
.SUBCKT FGH25T120SMD_Thermal TH TL
CTHERM1 TH 6 6.10e-4
CTHERM2 6 5  1.76e-3
CTHERM3 5 4  5.12e-3
CTHERM4 4 3  8.60e-3
CTHERM5 3 2  1.10e-2
CTHERM6 2 TL 3.01e-2
RTHERM1 TH 6 4.60e-4
RTHERM2 6 5  2.40e-3
RTHERM3 5 4  1.28e-2
RTHERM4 4 3  2.04e-2
RTHERM5 3 2  4.50e-2
RTHERM6 2 TL 2.69e-1
.ENDS FGH25T120SMD_Thermal
**----------------------------------------------------------------------------------
** Creation: Nov.-30-2016   Rev.: 1.0
** ON Semiconductor